mirror of
https://github.com/Mercury-Language/mercury.git
synced 2025-12-17 06:47:17 +00:00
62ec97d443
If a module has two or more import_module or use_module declarations
for the same module, (typically, but not always, one being in its interface
and one in its implementation), generate an informational message about
each redundant declaration if --warn-unused-imports is enabled.
compiler/hlds_module.m:
We used to record the set of imported/used modules, and the set of
modules imported/used in the interface of the current module. However,
these sets
- did not record the distinction between imports and uses;
- did not allow distinction between single and multiple imports/uses;
- did not record the locations of the imports/uses.
The first distinction was needed only by module_qual.m, which *did*
pay attention to it; the other two were not needed at all.
To generate messages for imports/uses shadowing other imports/uses,
we need all three, so change the data structure storing such information
for *direct* imports to one that records all three of the above kinds
of information. (For imports made by read-in interface and optimization
files, the old set of modules approach is fine, and this diff leaves
the set of thus *indirectly* imported module names alone.)
compiler/unused_imports.m:
Use the extra information now available to generate a
severity_informational message about any import or use that is made
redundant by an earlier, more general import or use.
Fix two bugs in the code that generated warnings for just plain unused
modules.
(1) It did not consider that a use of the builtin type char justified
an import of char.m, but without that import, the type is not visible.
(2) It scanned cons_ids in goals in procedure bodies, but did not scan
cons_ids that have been put into the const_struct_db. (I did not update
the code here when I added the const_struct_db.)
Also, add a (hopefully temporary) workaround for a bug in
make_hlds_passes.m, which is noted below.
However, there are at least three problems that prevent us from enabling
--warn-unused-imports by default.
(1) In some places, the import of a module is used only by clauses for
a predicate that also has foreign procs. When compiled in a grade that
selects one of those foreign_procs as the implementation of the predicate,
the clauses are discarded *without* being added to the HLDS at all.
This leads unused_imports.m to generate an uncalled-for warning in such
cases. To fix this, we would need to preserve the Mercury clauses for
*all* predicates, even those with foreign procs, and do all the semantic
checks on them before throwing them away. (I tried to do this once, and
failed, but the task should be easier after the item list change.)
(2) We have two pieces of code to generate import warnings. The one in
unused_imports.m operates on the HLDS after type and mode checking,
while module_qual.m operates on the parse tree before the creation of
the HLDS. The former is more powerful, since it knows e.g. what types and
modes are used in the bodies of predicates, and hence can generate warnings
about an import being unused *anywhere* in a module, as opposed to just
unused in its interface.
If --warn-unused-imports is enabled, we will get two separate set of
reports about an interface import being unused in the interface,
*unless* we get a type or mode error, in which case unused_imports.m
won't be invoked. But in case we do get such errors, we don't want to
throw away the warnings from module_qual.m. We could store them and
throw them away only after we know we won't need them, or just get
the two modules to generate identical error_specs for each warning,
so that the sort_and_remove_dups of the error specs will do the
throwing away for us for free, if we get that far.
(3) The valid/bug100.m test case was added as a regression test for a bug
that was fixed in module_qual.m. However the bug is still present in
unused_imports.m.
compiler/make_hlds_passes.m:
Give hlds_module.m the extra information it now needs for each item_avail.
Add an XXX for a bug that cannot be fixed right now: the setting of
the status of abstract instances to abstract_imported. (The "abstract"
part is correct; the "imported" part may not be.)
compiler/intermod.m:
compiler/try_expand.m:
compiler/xml_documentation.m:
Conform to the change in hlds_module.m.
compiler/module_qual.m:
Update the documentation of the relationship of this module
with unused_imports.m.
compiler/hlds_data.m:
Document a problem with the status of instance definitions.
compiler/hlds_out_module.m:
Update the code that prints out the module_info to conform to the change
to hlds_module.m.
Print status information about instances, which was needed to diagnose
one of the bugs in unused_imports.m. Format the output for instances
nicer.
compiler/prog_item.m:
Add a convenience predicate.
compiler/prog_data.m:
Remove a type synonym that makes things harder to understand, not easier.
compiler/modules.m:
Delete an XXX that asks for the feature this diff implements.
Add another XXX about how that feature could be improved.
compiler/Mercury.options.m:
Add some more modules to the list of modules on which the compiler
should be invoked with --no-warn-unused-imports.
compiler/*.m:
library/*.m:
mdbcomp/*.m:
browser/*.m:
deep_profiler/*.m:
mfilterjavac/*.m:
Delete unneeded imports. Many of these shadow other imports, and some
are just plain unneeded, as shown by --warn-unused-imports. In a few
modules, there were a *lot* of unneeded imports, but most had just
one or two.
In a few cases, removing an import from a module, because it *itself*
does not need it, required adding that same import to those of its
submodules which *do* need it.
In a few cases, conform to other changes above.
tests/invalid/Mercury.options:
Test the generation of messages about import shadowing on the existing
import_in_parent.m test case (although it was also tested very thoroughly
when giving me the information needed for the deletion of all the
unneeded imports above).
tests/*/*.{m,*exp}:
Delete unneeded imports, and update any expected error messages
to expect the now-smaller line numbers.
155 lines
4.8 KiB
Mathematica
155 lines
4.8 KiB
Mathematica
%---------------------------------------------------------------------------%
|
|
% vim: ft=mercury ts=4 sw=4 et
|
|
%---------------------------------------------------------------------------%
|
|
% Copyright (C) 1998-2000, 2003, 2005-2006 The University of Melbourne.
|
|
% This file may only be copied under the terms of the GNU Library General
|
|
% Public License - see the file COPYING.LIB in the Mercury distribution.
|
|
%---------------------------------------------------------------------------%
|
|
%
|
|
% File: frame.m.
|
|
% Author: aet.
|
|
%
|
|
% frame - minimally implements ASCII graphics frames.
|
|
% This module is used by the term browser for displaying terms.
|
|
%
|
|
% XXX: This implementation is:
|
|
% - very inefficient.
|
|
% - specific to our immediate needs, and could be made more general.
|
|
%
|
|
%---------------------------------------------------------------------------%
|
|
%---------------------------------------------------------------------------%
|
|
|
|
:- module mdb.frame.
|
|
:- interface.
|
|
|
|
:- import_module list.
|
|
:- import_module pair.
|
|
|
|
%---------------------------------------------------------------------------%
|
|
|
|
% XXX: Make frame type abstract instead?
|
|
:- type frame == list(string).
|
|
|
|
% We always clip from top-left corner, hence only one pair of
|
|
% coordinates is needed.
|
|
:- type clip_rect == pair(int, int).
|
|
|
|
% Width of a frame (horizontal size).
|
|
%
|
|
:- func hsize(frame) = int.
|
|
|
|
% Height of a frame (vertical size).
|
|
%
|
|
:- func vsize(frame) = int.
|
|
|
|
% Create a frame from a string.
|
|
%
|
|
:- func from_string(string) = frame.
|
|
|
|
% Stack (vertically glue) two frames, left-aligned.
|
|
%
|
|
:- func vglue(frame, frame) = frame.
|
|
|
|
% Juxtapose (horizontally glue) two frames, top-aligned.
|
|
%
|
|
:- func hglue(frame, frame) = frame.
|
|
|
|
% Clip a frame to the rectangle ((0,0),(X,Y)) where origin is on the
|
|
% top-left. Coordinate axes go down and right.
|
|
%
|
|
:- func clip(clip_rect, frame) = frame.
|
|
|
|
%---------------------------------------------------------------------------%
|
|
%---------------------------------------------------------------------------%
|
|
|
|
:- implementation.
|
|
|
|
:- import_module mdb.util.
|
|
|
|
:- import_module assoc_list.
|
|
:- import_module int.
|
|
:- import_module string.
|
|
|
|
%---------------------------------------------------------------------------%
|
|
|
|
from_string(Str) = [Str].
|
|
|
|
vglue(TopFrame, BottomFrame) = StackedFrame :-
|
|
% Glue frames vertically (stack). Align to left.
|
|
list.append(TopFrame, BottomFrame, StackedFrame).
|
|
|
|
hglue(LeftFrame, RightFrame) = GluedFrame :-
|
|
% Glue frames horizontally (juxtapose). align to top.
|
|
RVSize = vsize(RightFrame),
|
|
LVSize = vsize(LeftFrame),
|
|
( if RVSize < LVSize then
|
|
PadLines = LVSize - RVSize,
|
|
RightFrameNew = frame_lower_pad(RightFrame, PadLines),
|
|
LeftFrameNew = LeftFrame
|
|
else if LVSize < RVSize then
|
|
PadLines = RVSize - LVSize,
|
|
LeftFrameNew = frame_lower_pad(LeftFrame, PadLines),
|
|
RightFrameNew = RightFrame
|
|
else
|
|
LeftFrameNew = LeftFrame,
|
|
RightFrameNew = RightFrame
|
|
),
|
|
frame_right_pad(LeftFrameNew, PaddedLeftFrameNew),
|
|
util.zip_with(
|
|
(pred(S1::in, S2::in, S3::out) is det :-
|
|
string.append(S1, S2, S3)
|
|
), PaddedLeftFrameNew, RightFrameNew, GluedFrame).
|
|
|
|
% Add right padding. That is, add whitespace on right so that
|
|
% lines are all equal length.
|
|
%
|
|
:- pred frame_right_pad(frame::in, frame::out) is det.
|
|
|
|
frame_right_pad(Frame, PaddedFrame) :-
|
|
Lengths = list.map((func(Str) = string.length(Str)), Frame),
|
|
list.foldl(int.max, Lengths, 0, MaxLen),
|
|
list.map(subtract(MaxLen), Lengths, Paddings),
|
|
list.map(add_right_padding,
|
|
assoc_list.from_corresponding_lists(Frame, Paddings), PaddedFrame).
|
|
|
|
:- pred add_right_padding(pair(string, int)::in, string::out) is det.
|
|
|
|
add_right_padding(Str - Len, PaddedFrameStr) :-
|
|
list.duplicate(Len, ' ', PadChars),
|
|
string.from_char_list(PadChars, Padding),
|
|
string.append(Str, Padding, PaddedFrameStr).
|
|
|
|
% We need this since Mercury has no Haskell-ese operation sections.
|
|
%
|
|
:- pred subtract(int::in, int::in, int::out) is det.
|
|
|
|
subtract(M, X, Z) :-
|
|
Z = M - X.
|
|
|
|
% Add empty lines of padding to the bottom of a frame.
|
|
%
|
|
:- func frame_lower_pad(frame, int) = frame.
|
|
|
|
frame_lower_pad(Frame, PadLines) = PaddedFrame :-
|
|
list.duplicate(PadLines, "", Padding),
|
|
list.append(Frame, Padding, PaddedFrame).
|
|
|
|
hsize(Frame) = HSize :-
|
|
Lengths = list.map(func(Str) = string.length(Str), Frame),
|
|
list.foldl(int.max, Lengths, 0, MaxLen),
|
|
HSize = MaxLen.
|
|
|
|
vsize(Frame) = VSize :-
|
|
length(Frame, VSize).
|
|
|
|
clip(X-Y, Frame) = ClippedFrame :-
|
|
list.take_upto(Y, Frame, YClippedFrame),
|
|
list.map(left(X), YClippedFrame, ClippedFrame).
|
|
|
|
:- pred left(int::in, string::in, string::out) is det.
|
|
|
|
left(N, Str, Left) :-
|
|
string.left(Str, N, Left).
|
|
|
|
%---------------------------------------------------------------------------%
|