mirror of
https://github.com/Mercury-Language/mercury.git
synced 2026-04-20 11:54:02 +00:00
9b6390b17e
extras/curs/curs.m:
extras/curs/curs.panel.m:
Make panel a separate submodule of curs, not a nested submodule.
extras/base64/base64.m:
extras/curses/mcurses.basics.m:
extras/curses/mcurses.m:
extras/curses/mcurses.misc.m:
extras/curses/mcurses.user.m:
extras/gator/evolve.m:
extras/gator/genotype.m:
extras/gator/phenotype.m:
extras/gator/tausworthe3.m:
extras/monte/dots.m:
extras/monte/geom.m:
extras/monte/hg.m:
extras/monte/monte.m:
extras/monte/rnd.m:
extras/moose/grammar.m:
extras/moose/moose.m:
extras/mopenssl/mopenssl.m:
extras/net/echo.m:
extras/net/errno.m:
extras/net/getaddrinfo.m:
extras/net/net.m:
extras/net/netdb.m:
extras/net/sockets.m:
extras/net/streams.m:
extras/net/tcp.m:
extras/net/test_lookups.m:
extras/net/types.m:
extras/odbc/odbc.m:
extras/odbc/odbc_test.m:
extras/references/README:
extras/references/reference.m:
extras/references/scoped_update.m:
extras/solver_types/library/any.m:
extras/solver_types/library/any_array.m:
extras/solver_types/library/any_assoc_list.m:
extras/solver_types/library/any_list.m:
extras/solver_types/library/any_map.m:
extras/solver_types/library/any_tree234.m:
extras/solver_types/library/any_util.m:
extras/trail/trail.m:
extras/trailed_update/samples/interpreter.m:
extras/trailed_update/samples/vqueens.m:
extras/trailed_update/tests/var_test.m:
extras/trailed_update/tr_array.m:
extras/trailed_update/tr_store.m:
extras/trailed_update/trailed_update.m:
extras/trailed_update/unsafe.m:
extras/trailed_update/var.m:
Bring programming style up to date.
89 lines
2.3 KiB
Mathematica
89 lines
2.3 KiB
Mathematica
%---------------------------------------------------------------------------%
|
|
% vim: ft=mercury ts=4 sw=4 et
|
|
%---------------------------------------------------------------------------%
|
|
%
|
|
% N-queens program -- using the `var' module and freeze/2.
|
|
%
|
|
%---------------------------------------------------------------------------%
|
|
|
|
:- module vqueens.
|
|
|
|
:- interface.
|
|
|
|
:- import_module list, int, io.
|
|
|
|
:- pred main(io::di, io::uo) is cc_multi.
|
|
|
|
%---------------------------------------------------------------------------%
|
|
%---------------------------------------------------------------------------%
|
|
|
|
:- implementation.
|
|
|
|
:- import_module std_util.
|
|
:- import_module unsafe.
|
|
:- import_module var.
|
|
|
|
main(!IO) :-
|
|
( if data(Data), queen(Data, Out) then
|
|
io.print_line(Out, !IO)
|
|
else
|
|
io.write_string("No solution\n", !IO)
|
|
).
|
|
|
|
:- pred data(list(int)::out) is det.
|
|
|
|
data([1, 2, 3, 4, 5, 6, 7, 8, 9, 10]).
|
|
|
|
:- pred queen(list(int)::in, list(int)::out) is nondet.
|
|
|
|
queen(Data, Out) :-
|
|
same_len(Data, Posn),
|
|
safe(Posn),
|
|
qperm(Data, Posn, Posn2),
|
|
conv_posn(Posn2, Out).
|
|
|
|
:- pred same_len(list(int)::in, list(var(int))::out(list(any))) is det.
|
|
|
|
same_len([], []).
|
|
same_len([_ | Xs], [N | Ys]) :-
|
|
init(N),
|
|
same_len(Xs, Ys).
|
|
|
|
:- pred conv_posn(list(var(int))::in, list(int)::out) is det.
|
|
|
|
conv_posn([], []).
|
|
conv_posn([var(N) | Xs], [N | Ys]) :-
|
|
conv_posn(Xs, Ys).
|
|
|
|
:- pred qperm(list(int)::in, list(var(int))::in(list(any)),
|
|
list(var(int))::out) is nondet.
|
|
|
|
qperm([], [], []).
|
|
qperm([X | Y], [var(U) | V], [var(U) | V2]) :-
|
|
qdelete(U, [X|Y], Z),
|
|
qperm(Z, V, V2).
|
|
|
|
:- pred qdelete(int::out, list(int)::in, list(int)::out) is nondet.
|
|
|
|
qdelete(A, [A | L], L).
|
|
qdelete(X, [A | Z], [A | R]) :-
|
|
qdelete(X, Z, R).
|
|
|
|
:- pred safe(list(var(int))::in(list(any))) is semidet.
|
|
|
|
safe([]).
|
|
safe([NVar | L]) :-
|
|
freeze(NVar, (any_pred(N::in) is semidet :- nodiag(N, 1, L))),
|
|
safe(L).
|
|
|
|
:- pred nodiag(int::in, int::in, list(var(int))::in(list(any))) is semidet.
|
|
|
|
nodiag(_, _, []).
|
|
nodiag(B, D, [NVar | L]) :-
|
|
freeze(NVar, (any_pred(N::in) is semidet :- D \= N - B, D \= B - N)),
|
|
nodiag(B, D + 1, L).
|
|
|
|
%---------------------------------------------------------------------------%
|
|
:- end_module vqueens.
|
|
%---------------------------------------------------------------------------%
|